Calrouting scripts in v6.10 are still able to access the local hard disk. You have to change the script, however, because it uses PBXUser.Datafolder as root path to find the text file. In v6.10 PBXUser.Datafolder points to a temporary folder.

Change the script to use a fixed location on the hard disk and make sure that the file is located on a shared folder so that it can be accessed from a client PC.

The reason why other scripts also seizes to work is easy: your current script causes a runtime error which ends the call automatically.

Suggestion: replace all the following code

' get share path by extracting it from user folder

sDir = C:\

nPos = InStrRev(sDir, "\")

sDir = Left(sDir, nPos-1)

nPos = InStrRev(sDir, "\")

sDir = Left(sDir, nPos)

' Build file name. Textfile will be located within the global script directory, e.g.

' --> C:\Program Files\SwyxWare\Share\Data\PhoneClient\Scripts\bankholiday.txt

sFile = sDir & "holiday\" & sBHFilename

by

sFile = "C:\holiday.txt"

Further more make sure, that the user the SwyxServer service is running under has at least read access to this file.

Tom Wellige
(Lead Solution Consultant, Swyx)

I learned very early the difference between knowing the name of something and knowing something.
Richard P. Feynman

You're welcome

The reason for the replaced code was that in the past the file was located in the global sript folder. So the path needed to be calculated.

As there is no global script folder from v6.10 on the file needs to be located somewhere else. Of course it was also previously possible to do so. The idea behind using the global script folder was to keep all things related to each other together at one place.

Regards, Tom.

Tom Wellige
(Lead Solution Consultant, Swyx)

I learned very early the difference between knowing the name of something and knowing something.
Richard P. Feynman

Hello everybody,

I'm trying to use the script on a 6.12 version, but I always have disconnected. I have done the modify in the VB code of Start block as suggested  by Tom, but nothing has changed. I'll copy here the actual VB code, please tell me where's the error if possible, thanks:

' FileOpen iomode Values
Const fsoForReading   = 1
Const fsoForWriting   = 2
Const fsoForAppending = 8

Function IsBankHoliday ( vDate )

    Dim wsh, fso, file
    Dim sDir, sFile, sLine
    Dim bReturn, nPos

    bReturn = False

    sFile = "C:\holiday.txt"

    ' Create FileSystemObejct
    Set fso = CreateObject("Scripting.FileSystemObject")

    ' Open text file
    Set file = fso.OpenTextFile(sFile, fsoForReading)

    do while (not (file.AtEndOfStream)) and (not bReturn)
        sLine = file.ReadLine
        if IsDate(sLine) then
            if DateDiff("d", vDate, CDate(sLine)) = 0 then bReturn = True
        end if
    loop
    file.Close

    Set file = Nothing
    Set fso  = Nothing

    IsBankHoliday = bReturn

End Function

And the text file content:

31.10.2008

Seems if like the rule is skipped...any idea?

Thanks

thomas

Möchte mich schon vorab für die verwendete Sprache entschuldigen, mein Englisch reicht leider nicht...

Bin grad fleissig beim Testen und Probieren mit diesem schönen Skript, ich hätte es gerne dahingehend erweitert, dass in der Zeile der Feiertage hinten eine Rufnummer stehen kann, auf die dann entsprechend weitergeleitet wird. Wir haben in unserer Firma abwechselnd Bereitschaftsdienst und planen dies immer bereits für ein ganzes Jahr voraus, es wäre supertoll, wenn Swyx dahingehend vollautomatisiert werden könnte, ohne dass jeweils die Nummer, auf die umgeleitet wird, geändert werden muss.

Andere Frage: wo finde ich das TraceLog, um evtl. Fehler im Skript zu finden?

Schon mal vielen Dank im Voraus!

Vielen Dank, so ähnlich bzw. genauso hatte ich das auch probiert, aber offensichtlich sind die Scripts so "empfindlich", dass beim kleinsten Fehler nichts mehr geht (ist ja auch klar), wie könnte man solche Scripts ausserhalb con Swyx testen bzw. welche Software/Debugger würdest Du empfehlen?

Man kann sich das Ändern der Ausgabestatements zu WScript.Echo auch sparen, indem man eine eigene Implementierung von PBXScript für externe Tests baut:

 option explicit

' stub for the PBXScript object

' implements tracing and CreateObject functions only

class PBXScriptClass

    private currentTraceLevel

    public Sub PBXScriptClass_Initialize

        currentTraceLevel = 4

    end sub

    public property let TraceLevel(value)

        currentTraceLevel = value

    end property

    public property get TraceLevel

        TraceLevel = currentTraceLevel

    end property

    sub OutputTrace(msg)

        WScript.Echo msg

    end sub

    sub OutputTraceEx(level, msg)

        if currentTraceLevel >= level then

            WScript.Echo msg   

        end if

    end sub

    function CreateObject(o)

        CreateObject = WScript.CreateObject(o)

    end function

end class

dim PBXScript

set PBXScript = new PBXScriptClass

PBXScript.TraceLevel = 4

' load test code

PBXScript.OutputTrace "Testing custom VBScript " & WScript.Arguments(0)

dim oFSO

set oFSO = WScript.CreateObject("Scripting.Filesystemobject")

dim oFile

set oFile = oFSO.OpenTextFile(WScript.Arguments(0))

dim scriptToExecute

scriptToExecute = oFile.ReadAll

ExecuteGlobal scriptToExecute

PBXScript.OutputTrace "Done"

 Diesen Code speichert man als ecrtest.vbs ab. Sein eigenes Script testet man dann mit

cscript.exe ecrtest.vbs myscript.vbs

Das Script hätte ich soweit:

 Const sBuildNo        = "1.0.1"

' FileOpen iomode Values
Const fsoForReading   = 1
Const fsoForWriting   = 2
Const fsoForAppending = 8

' Bankholiday Filename
Const sBHFilename     = "BankHoliday.txt"

' use global script folder (oder users script folder ?
Const bGlobal         = True


Function IsHotline ( vDate )

    PBXScript.OutputTrace "--------> IsHotline ( " & CStr(vDate) & " ) - v" & sBuildNo

    Dim wsh, fso, file
    Dim sFile, sLine
    Dim bReturn, nPos
    Dim bRange, aRange, vStart, vEnd
    Dim HotlineNummer

    bReturn = False

    if bGlobal then
        sFile = "e:\swyx\ecr\hotline.txt"
    else
        sFile = "e:\swyx\ecr\hotline.txt"
    end if
    PBXScript.OutputTrace sFile

    ' Create FileSystemObejct
    Set fso = CreateObject("Scripting.FileSystemObject")

    ' Open text file
    Set file = fso.OpenTextFile(sFile, fsoForReading)

    do while (not (file.AtEndOfStream)) and (not bReturn)

        sLine  = file.ReadLine
        PBXScript.OutputTrace "sLine: " & sLine

        bRange = False
        aRange = Split(sLine, ";")

        if IsDate(aRange(0)) then
            vStart = CDate(aRange(0))
            PBXScript.OutputTrace "vStart: " & CStr(vStart)

            if UBound(aRange) > 0 then
                if IsDate(aRange(1)) then
                    bRange = True
                    vEnd = CDate(aRange(1))
                    PBXScript.OutputTrace "vEnd: " & CStr(vEnd)
                else
                    PBXScript.OutputTrace "invalid end date!"
                end if
            end if

            if not bRange then
                if (DateDiff("d", vDate, vStart) = 0) then bReturn = True
            else
                if (DateDiff("n", vStart, vDate) >= 0) and _
                    (DateDiff("n", vEnd, vDate) <= 0) then bReturn = True
            end if
        else
            PBXScript.OutputTrace "invalid start date!"
        end if

    loop

    HotlineNummer = aRange(2)

    if HotlineNummer = "Supra1" then
        HotlineNummer = "0348xxx"
    end if

    PBXScript.OutputTrace "Hotlinenummer: " & HotlineNummer

    file.Close

    Set file = Nothing
    Set fso  = Nothing

    IsHotline = bReturn

    PBXScript.OutputTrace "<-------- IsHotline returns: " & CStr(bReturn)

End Function

Genügt es aber, wenn ich beim Durchstellen-Block nun Ruf durchstellen für 90 Sekunden zu: =HotlineNummer schreibe?

Leider funktioniert mir das schon bei einer Mail-Benachrichtigung nicht, also mache ich da wohl etwas falsch.

Jepp, das wars, es ist also wichtig, WO dieses Dim HotlineNummer steht....

Tausend Dank, wieder ein Problem gelöst, heute ist ein guter Tag :-)